I. Les variables en Pascal Premiers programmes

1.Premiers programmes

Le programme 3aslema

Un programme est une suite d’instructions, certaines  étant des mots clés. Ce programme affiche la chaîne de caractères

« 3aslema » à l’ écran :

 

    PROGRAM Nom_du_programme;
    Uses Wincrt;
    BEGIN
        writeln (’3aslema’);
    END.

Le compilateur est un logiciel qui lit (analyse) un programme et le traduit en code machine, directement exécutable par le processeur de l’ordinateur.

 

 Commentaires dans un programme

On place un {commentaire} dans un programme au-dessus ou à coté d’une instruction.

Le commentaire n’est pas pris en compte à la compilation. Il sert à rendre le programme plus clair à la lecture, à noter des remarques, etc :

 

{ RMB=RéussirMonBac  } PROGRAM RMB;
Uses Wincrt;
BEGIN
{ Affiche 3aslema wmar7bé bikom ennes el kol fi réussirmonbac à l’écran }
    writeln (’3aslema wmar7bé bikom ennes el kol fi réussirmonbac’);
END.

Utilisation d’une variable entière

Une variable est une zone dans la mémoire vive de l’ordinateur, dotée d’un nom et d’un type. Le nom de la variable permet d’accéder au contenu de la zone mémoire ; le type spécifie la nature de ce qui peut être stocké dans la zone mémoire (entier, réel, caracère, etc).

On peut dire qu’une variable est une boîte ; dessous on met le nom, au dessus le type, et dans la boîte le contenu.

Exemple avec une variable de nom a et de type entier :

 

PROGRAM definir_une_variable;
Uses Wincrt;
VAR
    a : integer; { Déclaration. la variable a est un entier( 1 ; 5 ; 10 ; -17... }
BEGIN
    a := 5; { Affectation }
    writeln(’valeur de a=’,a); {Affichage à l'écran: a=5 }
END.

La structure de ce programme est en 3 parties: le nom du programme (Programm), la partie

déclarations(juste après Uses Wincrt; et avant Begin), et le corps du programme(entre BEGIN et END.), qui est une suite d’instructions.

La partie déclaration crée les variables (les boîtes) ; leur contenu est indéterminé (on met un ’ ?’ dans chaque boîte). La taille de la zone mémoire de chaque variable est adaptée au type (par exemple 1 octet pour un caractère, 4 octets pour un entier, etc).

Lecture au clavier d’une valeur

PROGRAM LireEtEcrire;
Uses Wincrt;
VAR
    a : integer;
BEGIN
write (’Entrez un entier : ’);  { write: PAS de retour à la ligne }
readln (a);                                 { Lecture }
 writeln (’valeur de a = ’, a);   { writeln:  de retour à la ligne }
END.

 

2.Identificateur

Sert à donner un nom à un objet.

Syntaxe
On appelle lettre un caractère de ’a’..’z’ ou ’A’..’Z’ ou ’_’.
On appelle digit un caractère de ’0’..’9’.
Un identificateur Pascal est une suite de lettres ou de digit accolés, commençant par une lettre.

Exemples

x, y1, jour, mois, annee, NbCouleurs, longueur_ligne.

Remarques

  • Il n’y a pas de différence entre minuscules et majuscules.
  • On n’a pas le droit de mettre d’accents, ni de caractères de ponctuation.
  • Un identificateur doit être différent des mots clés (begin, read, integer, program . . .)

On se sert des identificateurs pour: le nom du programme, les noms de variables, les noms de constantes, les noms de types.

3.Types prédéfinis

Un type décrit un ensemble de valeurs et un ensemble d’opérateurs sur ces valeurs.

Type entier : integer

Entier signé en complément à deux sur 16 ou 32 bits, selon machine et compilateur: 16 pour Turbo Pascal.

Sur 16 bits, à valeur dans −32768 … +32767 .
Sur 32 bits, à valeur dans −2147483648 … +2147483647 .

 

• Opérateurs sur les entiers :

 

abs(x)        valeur absolue de |x|.

pred(x)      x−1.

succ(x)       x+1.

odd(x)        true si x est impair, false sinon.

sqr(x)          le carré de x.

+x                   identité.

-x                   signe opposé.

x + y              addition.

x –  y              soustraction.

x *  y             multiplication.

x /  y            division, fournissant un résultat de type réel. ( 7/2=3,5)

x div y       dividende de la division entière de x par y. ( 7 div 2=3)

x mod y    reste de la division entière, avec y non nul. ( 7 mod 2=1)

 Remarques
* Attention, les opérateurs /, div et mod, produisent une erreur à l’exécution si y est nul.
* Lorsqu’une valeur (ou un résultat intermédiaire) dépasse les bornes au cours de l’exécution, on a une erreur appelée débordement arithmétique.

 

Type réel : real

Exemples de real

0.0 ; -21.4E3 (= −21, 4 × 1000 = −21400) ; 1.234E-2 (= 1, 234 × 0,01)

Opérateurs sur un argument x réel : abs(x), sqr(x), +x, -x.

• Si l’un au moins des 2 arguments est réel, le résultat est réel pour : x – y, x + y, x * y.  ( 7.0 – 3 = 4.0/ 7.0 real; 3 integer; 4.0 real)

• Résultat réel quel que soit  l’argument:  entier ou réel : x / y (y doit être non nul) ; fonctions sin(x), cos(x), exp(x), ln(x), sqrt(x) (square root, racine carrée).

• Fonctions prenant un argument réel et fournissant un résultat entier : trunc(x) (partie entière; trunc(7.432)= 7), round(x) (entier le plus proche;round(7,5)=8;round(7,4999999)=7). Si le résultat n’est pas représentable sur un integer (entier), il y a débordement.

 Type caractère : char

Le jeux des caractères comportant les lettres, les digits, l’espace, les ponctuations,etc, est codé sur un octet non signé.

Le choix et l’ordre des 256 caractères possible dépend de la machine et de la langue.

Sur PC, on utilise le code ASCII, où ’A’ est codé par 65, ’B’ par 66, ’a’ par 97, ’  ’ par 32, ’{’ par 123, etc.

Le code ascii est organisé comme suit : de 0 à 31, sont codés les caractères de contrôle (7 pour le signal sonore, 13 pour le saut de ligne, etc). De 32 à 127, sont codés les caractères et ponctuations standards et internationaux. Enfin de 128 à 255, sont codés les caractères accentués propres à la langue, et des caractères semi-graphiques.

• Les opérateurs sur les chars sont :

ord(c)    numéro d’ordre dans le codage ; ici « code ascii ». (ord(b)=98)
chr(a)    le résultat est le caractère dont le code ascii est a. (chr(97)=’a’; chr(100)=’d’)

succ(c)   caractère suivant c dans l’ordre ascii ⇔ chr(ord(c)+1) (succ(A)=’B’)

prec(c)   caractère précédent c dans l’ordre ascii.

Remarque Il y a erreur à l’ex écution si le caractère n’existe pas.

Exemple

PROGRAM caracteres;
Uses Wincrt,
VAR
  c, d : char;
  a    : integer;

BEGIN
 c := ’F’;
 a := ord(c); { 70 }
 writeln (’Le code ascii de ’, c, ’ est ’, a);
 a := 122;
 c := chr(a); { ’z’ }
 writeln (’Le caractere de code ascii ’, a, ’ est ’, c);
 c := ’j’;
 d := succ(c); { ’k’ }
 writeln (’Le caractere suivant ’, c, ’ est ’, d);
END.

Exercice: Afficher les caractères de code ascii de 32; 35 ; 40 et 254 255

Divers
– On peut remplacer chr(32) par #32, mais pas chr(i) par #i.

– Le caractère apostrophe se note ’’’’.

 

• Une suite de caractères telle que ’Il y a’ est une chaîne de caractères ; il s’agit d’un objet de type string, que l’on verra plus loin.

 

Type booléen : boolean

Utilisé pour les expressions logiques.

 Deux valeurs : false (faux) et true (vrai).
• Opérateurs booléens :

not (négation), and (et), or (ou).

Exemple

{ Declaration }
 petit, moyen, grand : boolean;
{ Instructions }
 petit := false;
 moyen := true;
 grand := not (petit or moyen); {not(false or true) = not(true) = false}

Table de v ́erit ́e de ces op ́erateurs

x y not x

x and y x or y true true false true false true

table de vérité  de ces opérateurs
X Y not X
X and Y X or Y
 false false true false false
false true true false true
true false false false true
true true false true true

• Opérateurs de comparaison (entre 2 entiers, 2 réels, 1 entier et 1 réel, 2 chars, 2 booléens) :
<, >, <=, >=, = (égalité, à ne pas confondre avec l’attribution :=), <> (diff érent).

Le résultat d’une comparaison est un booléen.
On peut comparer 2 booléens entre eux, avec la relation d’ordre false < true. (false= 0 , true= 1)

• En mémoire, les booléens sont codés sur 1 bit, avec 0 pour false et 1 pour true. Les opérateurs booléens not, and, or s’apparentent approximativement à (1 − x), ×, +.

4.Déclarations

Constantes

Une constante est désignée par un identificateur et une valeur, qui sont fixés en début de programme, entre les mots clés CONST et VAR.

La valeur ne peut pas être modifiée, et ne peut pas être une expression.

Syntaxe

identificateur = valeur_constante;

ou

identificateur : type = valeur_constante;

Dans la première forme, le type est sous-entendu (si il y a un point, c’est un réel, sinon un entier ; si il y a des quotes, c’est un caractère (un seul) ou une chaîne de caractères (plusieurs).

 

Exemple

PROGRAM constantes;
Uses Wincrt;
CONST
  faux = false;
  entier = 20;
  reel = 0.0;
  carac = ’z’;
  chaine = ’RMB’;
  pourcent : real = 33.3; {autres forme de déclaration}
VAR
{ variables }

BEGIN

{ instructions }

END.

 

Variables et affectation

 

Une variable représente un objet d’un certain type; cet objet est désigné par un identificateur. Toutes les variables doivent être déclarées après le VAR.

Syntaxeidentificateur : type ;

On peut déclarer plusieurs variables de même type en même temps, en les séparant par des virgules (voir exemple).

À la déclaration, les variables ont une valeur indéterminée. On initialise les variables juste après le BEGIN (on ne peut pas le faire dans la déclaration).

Utiliser la valeur d’une variable non initialisée est une erreur grave !!! :O

Exemple

 

VAR
        a, b, c : integer;
BEGIN
{ Partie initialisation }
b := 5;
 { Partie principale }
 a:=b+c; {ERREUR,c n’est pas affecté}
END.

L’opération identificateur := expression; est une affectation. On n’a pas le droit d’ écrire id1 := id2 := expr , ni expr := id ni expr1 := expr2 .

 

 5.Expressions

Une expression désigne une valeur, exprimée par composition d’opérateurs appliqués à des opérandes, qui sont : des valeurs, des constantes, des variables, des appels à fonction ou des sous-expressions.

Exemple . Étant donné une variable x, une constante max et une fonction cos(), chaque ligne contient une expression :

5
x + 3.14
2 * cos(x)
(x < max) or (cos(x-1) > 2 * (x+1))

 Syntaxe

Certains opérateurs agissent sur 2 opérandes :

operande1    operateur_binaire      operande2

et d’autres agissent sur 1 opérande :

                                        operateur_unaire   operande

• Les opérateurs binaires sont :

– Opérateurs de relation        = <> <= < > >=

– Opérateurs additifs              + – or

– Opérateurs multiplicatifs  * / div mod and

• Les opérateurs unaires sont :
– Opérateurs de signe            + –

– Opérateur de négation        not

• Les parenthèses sont un opérateur primaire, elles peuvent encadrer tout opérande.

• Une fonction est aussi un opérateur primaire, elle agit sur l’opérande placé entre parenthèses à sa droite. Certaines fonctions ont plusieurs paramètres, séparés par des virgules.

Type des expressions bien formées

Une expression doit être « bien formée » pour que l’on puisse trouver sa valeur. Par exemple, 3 * ’a’ – true n’est pas bien formée, et la compilation Pascal échouera.

Dans la partie 3, Types prédéfinis, on a déjà dit quels opérateurs sont applicables sur quels types. Mais il y a encore d’autres règles, dont le simple bon-sens !

L’expression bien formée a un type, qui dépend des règles d’évaluation de l’expression.

Exemple
Soit r un réel, i un entier, e une constante entière, c un caractère. L’expression

( round(r+1)  > (i/e) ) or ( c < ’a’ )

est bien formée, et son type est booléen comme on le montre ici :

Screen Shot 2016-01-05 at 2.41.29 PM

Remarque
Le fait qu’une expression est bien formée n’implique pas que son évaluation est sans erreur, ce qui peut être le cas ici si e est nul.

 

Règles d’évaluation

L’expression a + b * c est évaluée a + (b * c) et non pas (a + b) * c :ceci parce que le * est prioritaire par rapport à  + ou .

On classe les différents opérateurs par ordre de priorité, les opérateurs de plus forte priorité étant réalisés avant ceux de plus faible priorité.

Lorsque deux opérateurs sont de priorité égale, on évalue de gauche à droite. Par exemple a + b – c est évalué (a + b) – c, et non pas a + (b – c).

Voici la table des priorités classées par ordre décroissant, les opérateurs sur une même ligne ayant une priorité égale.

 

() fonction()

+ – not

* / div mod and

+ – or

= <> < <= >= >

primaire

unaire

multiplicatif

additif

relation

Remarque

Est-ce que l’expression a < b or c <= d est bien formée ? Quel est son type ?

Réponse : non!  Ecrire une telle expression booléenne sans parenthèses est une erreur classique.

En effet dans la table de priorités, l’opérateur or a une priorité plus élevée que les opérateurs < et <=, et donc l’expression sera  évaluée a < (b or c) <= d , ce qui est faux.

L’expression bien formée est ici   (a < b) or (c <= d) .

 

 

6.Nouveaux types

On a vu les types pré-déclarés boolean, integer, real et char.

Nous verrons par la suite comment créer de nouveau types. Nous commençons par les plus simples, le type intervalle et le type énuméré.

 Type intervalle

C’est un sous-ensemble de valeurs consécutives d’un type hôte.

Syntaxe N..M
N et M sont des constantes du même type, et sont les bornes inférieures et supérieures de l’intervalle, N et M inclus.

Exemple

VAR

pourcentage : 0 .. 100; {le type hôte est integer}

digit : ’0’ .. ’9’; {le type hôte est char}

reponse : false .. true;{le type hôte est boolean}


 

Remarques

  • Il faut impérativement que le type hôte soit codé sur un entier (signé ou non, sur un nombre de bits quelconque). On dit alors que ce type hôte est un type ordinal.
  •   Ainsi les types integer, char et boolean sont des types ordinaux.
  •  Seul un type ordinal admet les opérateurs pred, succ et ord (le précédent, le successeur et le numéro d’ordre dans le codage).
  • Par contre le type real n’est pas ordinal, et donc on ne pas créer un type intervalle avec des réels, il n’y a pas de notion de « réels consécutifs ».
  • Un autre cas de type non ordinal est le type string pour les chaînes de caractères, qui n’est pas codé sur un mais sur plusieurs entiers. On ne peut donc pas déclarer ’aaa’..’zzz’.

Bonne habitude Utiliser des constantes nommées pour borner les intervalles : de la sorte on pourra consulter ces valeurs pendant le programme, et ces bornes ne seront écrites qu’une seule fois.

Exemple

CONST
    PMin = 0;
    PMax = 100;
VAR
    pourcentage : PMin .. PMax;
BEGIN
writeln (’L’’intervalle est ’, PMin, ’ .. ’, PMax); 
END.

Type énuméré

Il est fréquent en programmation que l’on aie à distinguer plusieurs cas, et que l’on cherche à coder le cas à l’aide d’une variable.

Exemple

VAR
        feux : 0..3; {rouge, orange, vert, clignotant}
BEGIN
{ ... }
 if feux = 0 
then Arreter
 else if feux =1
 then Ralentir
 else if feux =2
{ ... }
END.

 

Ceci est très pratique mais dans un programme un peu long cela devient rapidement difficile à comprendre, car il faut se souvenir de la signification du code.

D’où l’intérêt d’utiliser un type énuméré, qui permet de donner un nom aux valeurs de code :

VAR
 feux : (Rouge, Orange, Vert, Clignotant);
BEGIN
 { ... }
 if feux = Rouge
 then Arreter
 else if feux = Orange then Ralentir
 else if feux = Vert
 { ... }
END.

• En écrivant cette ligne, on déclare en même temps :
– la variable feux, de type énuméré (toujours codée sur un entier),

– et les constantes nommées Rouge, Orange, Vert et Clignotant.

• À ces constantes sont attribuées les valeurs 0, 1, 2, 3 (la première constante prend toujours la valeur 0).

– On ne peut pas choisir ces valeurs soi-même, et ces identificateurs ne doivent pas déjà exister.

– L’intérêt n’est pas de connaître ces valeurs, mais d’avoir des noms explicites.

• Le type énuméré étant codée sur un entier, il s’agit d’un type ordinal et on peut:

– utiliser les opérateurs pred, succ et ord (exemple : pred(Orange) est Rouge,

succ(Orange) est Vert, ord(Orange) est 1).
– Déclarer un type intervalle à partir d’un type énuméré (exemple : Rouge..Vert).

Déclarer un type

Créer un type, c’est bien, mais le nommer, c’est mieux. On déclare les noms de types entre les mots clés TYPE et VAR.

Syntaxe

  nom_du_type = type;

Exemple

TYPE
      couleurs = (Rouge, Orange, Vert, Clignotant);
VAR
      feux : couleurs;

De la sorte couleurs est un nom de type au même titre que integer ou char.

Exemple complet

PROGRAM portrait;
Uses Wincrt
   
CONST
   TailleMin = 50; {en cm}
   TailleMax = 250;

TYPE
   taille_t = TailleMin .. TailleMax;
   couleurs_t = (Blond, Brun, Roux, Bleu, Marron, Noir, Vert); 
   cheveux_t = Blond .. Roux;
   yeux_t = Bleu .. Vert;
VAR
   taille_borhene, taille_lamia   : taille_t;
   cheveux_borhene, cheveux_lamia : cheveux_t;
   yeux_borhene, yeux_lamia       : yeux_t;
    
BEGIN
taille_borhene := 180;
cheveux_borhene:= Brun;
yeux_borhene   := Noir;
END.

Remarque Observez bien les conventions d’écriture différentes que j’ai employées pour distinguer les constantes des types et des variables; cela aide aussi à la lecture.

Facebook